Object-Oriented Programming

Handling Complexity: Since many computer applications address complex problems, problem-solving with computers must include a consideration of the handling of complexity. Already in this course, we have seen several such strategies and use a variety of language capabilities.

• Solutions can be built up using a sequence of procedures, where each procedure accomplishes a relatively simple task.

• Local variables and parameters allow work within a procedure to focus on a narrow, tightly controlled task even if the procedure will be used within a more complex problem.

• Using recursion, processing can focus on relatively simple base cases and the reduction of complex cases to simpler ones.

• Data abstraction allows data to be viewed in logical groups and structures, such as lists, vectors, association lists, and records.

• Procedural abstraction allows general procedures to be defined abstractly to cover many types of cases; mechanisms for variable arity procedures, procedure parameters, and currying give flexibility and allow general procedures to be tailored to specific needs.

• Libraries allow commonly used operations to be developed once and reused in other applications.

For example, association lists allow a natural matching of keyword and data, so we can focus upon the storage and retrieval of these information pairs. The assoc procedure retrieves relevant data, and we need not be bothered about the details of this retrieval. Similarly, the records lab shows how to think of data elements as part of a logical structure, with natural storage and retrieval operations.

1. Identify how you have used each of the above approaches or capabilities in the solving of at least two specific problems during this course.

In sections 12.2.2 through 12.2.5, the textbook describes four simple examples of ADTs as boxes, counters, accumulators, and gauges. Here, we consider the Stack ADT as an illustration -- expanding the discussion in section 12.3 of the textbook.

Stacks as ADTs: Conceptually, the stack abstract data type mimics the information kept in a pile on a desk. Informally, we first consider materials on a desk, where we may keep separate piles for bills that need paying, magazines that we plan to read, and notes we have taken. These piles of materials have several properties. Each pile contains some papers (information). In addition, for each pile, we can do several tasks:

• Start a new pile,
• Place new information on the top of a pile,
• Take the top item off of the pile,
• Read the item on the top, and
• Determine whether a pile is empty. (There may be nothing at the spot where the pile should be.)

When discussing these operations it is customary to call the addition of an item to the top of the pile a Push operation and the deletion of an item from the top a Pop operation.

More formally, a stack is defined as an abstract data type that can store data and that has the following operations:

• Make-Stack
  Create a new, empty stack object.
• Empty
  The Empty returns true or false (#t or #f), depending upon whether the stack contains any items or not.
• Push
  If the stack is not full, Push adds the specified item to the top of the stack.
  If the stack is full, nothing is added, and an error is reported.
• Pop
  If the stack is not empty, Pop removes the top item from the stack, and this item is returned.
  If the stack is empty, nothing is returned, and an error is reported.
• Top
  If the stack is not empty, the top item is returned, but the contents of the stack are not changed.
  If the stack is empty, nothing is returned, and an error is reported.

A Push operation always puts the new item on top of the stack, and this is the first item returned by a Pop operation. Thus, the last piece of data added to the stack will be the first item removed.

Classes, Objects, and Messages: One approach to problem solving involves an initial focus on data elements, operations on those elements, and relationships among data. Within computer science, such an approach motivates the viewpoint of object-oriented programming or OOP. When working within a OOP framework, it is useful to distinguish between the general notion of an abstract data type and specific uses of the ADT with definite data values. (For example, in Scheme we have found it useful to distinguish between an integer type and specific integer values.) Within OOP, the definition of an ADT (involving data variables and operations) is called a class, and specific instances of an ADT (with specific data values) are called objects.

Utilizing the notion of abstraction, we think of objects as self-contained entities, just as we might consider each pile on a desk as an separate, independent collection of material. To support this image, processing involving objects consists of sending messages to the objects, letting the object react to the object in an appropriate way, and receiving responses back. Within an OOP context, a mechanism for interpreting messages is called a method. For example, if our desk had two piles -- one for magazines and one for bills, we might have the following interaction:

> (define mag-pile (make-stack))     ; make stack for magazines
> (define bill-pile (make-stack))    ; make stack for bills
> (bill-pile 'push! "mortgage")      ; send push message to bill-pile
> (bill-pile 'push! "doctor's bill")
> (bill-pile 'push! "credit card")
> (bill-pile 'empty?)                ; send empty? message to bill-pile
#f                                   ; response from empty? message
> (mag-pile 'empty?)
#t
> (mag-pile 'push! "Communications of the ACM - April 1997")
> (mag-pile 'push! "CS Education Bulletin - Spring 1997")
> (bill-pile 'top)                   ; send top message to bill-pile
"credit card"                        ; data returned as message response
> (mag-pile 'top)
"CS Education Bulletin - Spring 1997"
> (bill-pile 'pop!)
"credit card"
> (bill-pile 'top)
"doctor's bill"

(define make-stack
   (lambda ()
     (let ((stk '()))
        (lambda (message . args)
           (case message   ;; identify and respond to various messages
                ((empty?) (null? stk))

                ((push!) (set! stk (cons (car args) stk)))

                ((top) (if (null? stk)
                           (error 'stack-adt "top: The stack is empty")
                           (car stk)))

                ((pop!) (if (null? stk)
                          (error 'stack-adt "pop!: The stack is empty")
                          (let ((result (car stk)))
                            (set! stk (cdr stk))
                            result)))

                ;; It is an error to send the stack any other message.
                (else (error 'stack-adt "stack: unrecognized message")))))))

Operations On A Stack: Beyond the declaration of a local variable, a stack responds to various messages. Following Scheme's syntax for procedures of variable arity, a stack requires a message as a first parameter. The processing of some messages may require further information, so additional parameters, if any, are collected in the args list.

2. Define two stacks and perform some operations on them, following the script given earlier in this lab. In each case, be sure you have a conceptual understanding of the results.

(cond ((eq? message 'empty?) ...)
       (eq? message 'push!)  ...)
       (eq? message 'top)    ...)
       (eq? message 'pop)    ...)
       (else                 ...))
)

(case message
     ((empty)     ...)
     ((push!)     ...)
     ((pop!)      ...)
     ((top)       ...)
     (else        ...)
)

Additional examples using the case special form are given in section 12.2.1 of the textbook.

3. Define vowel-or-consonant as shown in the textbook, and check it with various test cases.

4. Expand the stack ADT by adding
   • a size method which will return the number of items currently on the stack,

   • a print method which will print all of the current elements on the stack, and

   • an nth method which takes one parameter (an index) and returns the item at that position from the top in the current stack.